On Error Resume Next

Dim fso, oFile
Dim sData

Set fso = CreateObject("Scripting.FileSystemObject")

If Err.Number = 0 And fso.FileExists("c:\Prefs.txt") Then
	'Create File with Property Values from BAMViewer
	sData = "C:\Program Files\Benefits Reporting Package\"
	If fso.FileExists(sData & "BAMViewer.mde") Then
		Dim rs, sSQL, sConn, i, sRecInfo, sTable, sFields, sValues
		sConn = "Provider=Microsoft.Jet.OLEDB.4.0;Data Source=" & sData & "BAMViewer.mde;Persist Security Info=False"
	
		'Open file.
		Set oFile = fso.OpenTextFile("c:\Prefs.txt")
        	'Loop while not at the end of the file.
        	Do While Not oFile.AtEndOfStream
        		sRecInfo = oFile.ReadLine
			Select Case Mid(sRecInfo,1,3)
				Case "[Pr"
					sTable = "tblPreference"
				Case "[Mu"
					sTable = "tblMultiUser"
				Case "[Ad"
					sTable = "tblAddressBook"
				Case "Fie"
					sFields = RTrim(Mid(sRecInfo,InStr(sRecInfo,"=") + 1))
					sFields = Split(sFields,",")
				Case "Rec"
					sValues = RTrim(Mid(sRecInfo,InStr(sRecInfo,"=") + 1))
					sSQL = "SELECT * FROM " & sTable
					Set rs = CreateObject("ADODB.Recordset")
					rs.Open sSQL, sConn, 1, 3
					sValues = Split(sValues,",")
					For i = LBound(sValues) to UBound(sValues)
						sValues(i) = Replace(sValues(i),"~",",")
						If sValues(i) = "" Then sValues(i) = " "
					Next
					
					If sTable <> "tblPreference" Then
						rs.AddNew sFields, sValues
						rs.Update
					Else
						rs.Update sFields, sValues
					End If

					rs.Close
					Set rs = Nothing
			End Select
        	Loop

		'Close the file.
        	oFile.Close
		fso.DeleteFile("c:\Prefs.txt")
		Set oFile = Nothing
		Set fso = Nothing
		Set rs = Nothing
	End If
	If Err.Number = 0 Then
		MsgBox "Successfully transferred Preferences.", 0, "Transfer Status"
	Else
		MsgBox "Preference transfer failed. Please contact AmeriBen Solutions to help reset Preferences.", 0, "Transfer Status"
	End If
End If

Err.Clear